APDL 2D pressure analysis of cylinder with dual bore 1

[braunboise]

I have a cylinder with dual bore and is interested to see the effect of applying pressure to one of the bore. I wrote a code for APDL in 2D for my problem but saw an error message "both solid model and finite element model boundary conditions have been applied to this model.....". The analysis did run but i believe is incorrect. Would anyone be able to advice what was wrong? I have attached my code for reference.

 

[Erik Panos Kostson]

The warning (it is not an error), says, that displacements on nodes (FEA), and pressures on lines (solid body) are mixed together (I assume that is fine, it is just for the user to be aware).

With the apdl code below you do not get this as they are applied on KeyPoints (KP). Also two KP need to be restrained to avoid rotation about the node initially restrained (if two are fixed then we can not get rotation). With these 2 points fixed the model does not have any strange rigid body motion, as one wants.

/PREP7

ET,1,PLANE183

!MATERIAL PROPERTIES
!CYLINDER 1
MP,EX,1,29.6E6		!YOUNG MOD
MP,NUXY,1,0.3		!

!FRICTION
MP,MU,100,0		!0 EQUALS NO FRICTION

BOPTN,KEEP,NO

HGR_R = (6.250+0.002)/2	!BORE 1 RADIUS
ESP_R = (2.889+0.002)/2	!BORE 2 RADIUS
OS_HGR = 1.920-0.005	!BORE 1 OFFSET FROM CL
OS_ESP = 2.979-0.005	!BORE 2 OFFSET FROM CL
BNT_R = 12/2		!OUTER R OF CYLINDER

!HANGER OD

K,1,-BNT_R,0.00
K,2,0.00,BNT_R
K,3,BNT_R,0.00
K,4,0.00,-BNT_R

K,5,-OS_HGR-HGR_R,0.00
K,6,-OS_HGR,HGR_R
K,7,-OS_HGR+HGR_R,0.00
K,8,-OS_HGR,-HGR_R

K,9,OS_ESP-ESP_R,0.00
K,10,OS_ESP,ESP_R
K,11,OS_ESP+ESP_R,0.00
K,12,OS_ESP,-ESP_R

!CREATE LINES
!CYLINDER 1
LARC,1,2,3,BNT_R
LARC,2,3,1,BNT_R
LARC,3,4,1,BNT_R
LARC,4,1,3,BNT_R

LARC,5,6,7,HGR_R
LARC,6,7,5,HGR_R
LARC,7,8,5,HGR_R
LARC,8,5,7,HGR_R

LARC,9,10,11,ESP_R
LARC,10,11,9,ESP_R
LARC,11,12,9,ESP_R
LARC,12,9,11,ESP_R

!AREAS
LSEL,S,LINE,,1,4	!AREA 1
AL,ALL

LSEL,S,LINE,,5,8	!AREA 2
AL,ALL

LSEL,S,LINE,,9,12	!AREA 3
AL,ALL

ALLSEL

ASBA,1,2
ASBA,4,3
ALLSEL

ESIZE,0.20		!GENERIC MESH SIZE

LSEL,S,LINE,,5,8,1,1	!MESH SIZE BY LINE FOR CYLINDER 2
LESIZE,ALL,0.05
ALLSEL

LSEL,S,LINE,,9,12,1,1	!MESH SIZE BY LINE FOR CYLINDER 2
LESIZE,ALL,0.05
ALLSEL

TYPE,1			!CYLINDER 1 USING ET1, MAT1, AREA 1
MAT,1			!START MESHING	
AMESH,1

!RESTRAIN
KSEL,S,KP,,2,3,1
!D,80,ALL,0
DK,ALL, ,0, ,0,ALL, , , , , ,
ALLSEL

WSORT   
SAVE
FINISH

/SOLUTION

SOLCONTROL,ON
NLGEOM,ON
NSUBST,2

/TITLE,4000 PSI INTERNAL
LSEL,S,LINE,,5,8,1,1
SFL,ALL,PRES,4000
ALLSEL

SOLVE
SAVE
FINISH

 

[braunboise]

Erik, thanks! Your suggested BC works. Expanding on the question, how would you define the BC or symmetry if this is a 3D FEA using 180 degree model? Reference code attached.

 

[Erik Panos Kostson]

I would just take one node at the top far from the highest stressed area, and restrain X, and Y (Z is restrained), and a node next to it, say on the same edge, with Y fixed (this will prevent rotation about Z).

You could also cut this part along the length in half and restrain the Y dof on that symmetry plane,also preventing rotation about Z. Thus the only restrain needed is a single one at the top on a single KP, with X fixed (so it does not slide along x.)

Whatever you do look on the reactions there and see that they are small.

Here are some good links for restraints and rigid body motion:

http://help.solidworks.com/2012/eng...odels.htm?id=257d5973d5474d729eb2a558f5e5d5de

https://www.eng-tips.com/viewthread.cfm?qid=239491

You could also take this in to workbench and use automatic weak springs which is nice and check the reactions on them (do not know how to automatic use weak springs in apdl, not sure if possible even)