Batch Files from Excel 3

[gb433054]

Does anyone know if it is possible to run a batch file from an excel macro? I've tried using

Application.Run "C:\temp\MyBatchFile.bat"

But that didnt work

anyone got any ideas

 

[123121]

Use following code:

Shell "C:\temp\MyBatchFile.bat",vbNormalFocus

instead of vbNormalFocus you can use different from list

Thanks,
Vlado

 

[gb433054]

I new it was something like that, its that long since I used that command,

Thanks alot

Dave

 

[dsi]

If you need to wait until the batch file is done before proceeding with your code, you can use this method.

Option Explicit

Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long
Private Declare Function OpenProcess Lib "kernel32" (ByVal dwDesiredAccess As Long, ByVal bInheritHandle As Long, ByVal dwProcessId As Long) As Long
Private Declare Function WaitForSingleObject Lib "kernel32" (ByVal hHandle As Long, ByVal dwMilliseconds As Long) As Long

Private Const SYNCHRONIZE = &H100000
Private Const INFINITE = -1&

Sub Main()
    Dim sPrgm As String
    
    sPrgm = "C:\Winnt\notepad.exe"
    
    RunUntilFinished sPrgm
    
    MsgBox "App is finished!"

    End
End Sub

Public Sub RunUntilFinished(ByVal sApp As String)
    Dim lProcID As Long
    Dim hProc As Long

    ' Start the App
    On Error GoTo ErrHndlr
    lProcID = Shell(sApp, vbNormalFocus)
    On Error GoTo 0

    DoEvents

    ' Wait for the App
    hProc = OpenProcess(SYNCHRONIZE, 0, lProcID)
    If hProc <> 0 Then
        WaitForSingleObject hProc, INFINITE
        CloseHandle hProc
    End If
    Exit Sub

ErrHndlr:
    MsgBox &quot;Error starting App:&quot; & vbCrLf & _
           &quot;App: &quot; & sApp & vbCrLf & _
           &quot;Err Desc: &quot; & Err.Description
    Err.Clear
End Sub

DimensionalSolutions@Core.com
While I welcome e-mail messages, please post all thread activity in these forums for the benefit of all members.

 

[gb433054]

Excellent, I was just pondering over that problem. That deserves a star.

cheers

Dave