Can you post picture of complete model or problem definition? I guess you are over constraining the MPC element by applying boundary conditions at the common master node end. I assume you are specifying the revolute joint for MPC184 elements to simulate hinge support.

Could you specify the revolute joint as grounded and check? Probably the master node as grounded. See "MPC184" in help manual for more information.

Hey NRP99,

thanks for your answer! I will upload a picture of the model (at the end of the reply). I used rigid beam for the MPC184 elements, but I´ll try the revolute joint option. And yes, i think you are right that the applied boundary conditions at the master nodes are causing the problems. I have constrained the master nodes in all translational directions, so it should be 'grounded' right?

I'm also uploading my script if you want to take a look at it. I changed the applied surface pressure to be smaller so the nonlinear calculation doesn't abort, but in reality it will be much larger. Thanks in advance!

FINISH
/CLEAR

! system parameters

eSteel = 2.1e11 ! E-Module Steel [N/m²]
pSteel = 0.3 ! Poisson's ratio Steel [-]
dSteel = 7.850e3 ! Density Steel [kg/m³]

width = 0.3
length = 4
height = 8
thickness = 0.03

! yield and fracture limits [N/m²]
fy = 235e6
fu = 360e6
ey = fy/eSteel
eu = 0.26

! nonlinear analysis increments
delta_t = 0.05 ! start value of the iteration
delta_t_min = 1e-5 ! minimum increment
delta_t_max = 0.1 ! maximum increment

LOCAL,11,0,length+width,0,0
LOCAL,12,0,2*(length+width),0,0
CSYS,0

ymn = 1/5000

/PREP7

ET,1,Shell281
MP,EX,1,eSteel
MP,NUXY,1,pSteel
MP,DENS,1,dSteel
TB,KINH,1,1,2
TBPT,DEFI,ey,fy
TBPT,DEFI,eu,fu
SECTYPE,1,shell
SECDATA,thickness,1
SECDATA,NUMPT,1,5
KEYOPT,1,4,0

! master nodes for hinged support (not coincident)
N,1,width/2,-ymn
CSYS,12
N,2,-width/2,-ymn
CSYS,0

! 2-joint frame
K,1,0,0,-width/2
K,2,0,0,width/2
K,3,0,height,width/2
K,4,0,height,-width/2
A,1,2,3,4

K,5,width,0,-width/2
K,6,width,0,width/2
K,7,width,height-width,width/2
K,8,width,height-width,-width/2
A,5,6,7,8

K,9,length+width,height,-width/2
K,10,length+width,height,width/2
K,11,length+width,height-width,-width/2
K,12,length+width,height-width,width/2
A,3,4,9,10
A,7,8,11,12
A,9,10,12,11
A,1,5,6,2

RECTNG,0,width,0,height
RECTNG,width,length+width,height-width,height

ASEL,s,loc,y,0
AGEN,2,all,,,,height-width,,,
ALLSEL
ASEL,s,loc,x,length+width
AGEN,2,all,,,-length,,,,
ALLSEL

APTN,all

ASEL,s,loc,y,height-width
ASEL,r,loc,x,width/2
ADELE,all
ASEL,s,loc,y,height-width/2
ASEL,r,loc,x,width
ADELE,all

LESIZE,all,0.1,,
MSHKEY,1
MSHAPE,0
TYPE,1
MAT,1
SECN,1
ALLSEL
AMESH,ALL
ALLSEL

CSYS,11
ASEL,u,loc,x,0
ARSYM,x,all
ALLSEL
CSYS,0

NUMMRG,all

! MPC184-element
ET,11,MPC184
KEYOPT,11,1,1
KEYOPT,11,2,1
R,11,1

TYPE,11
REAL,11

ASEL,s,loc,x,width/2
ASEL,r,loc,y,0
NSLA,s,1
*get,ncount,node,,count

*DO,i,1,ncount,1
*GET,nmax,node,0,num,max
E,1,nmax
NSEL,u,node,,nmax
*ENDDO

CSYS,12
ASEL,s,loc,x,-width/2
ASEL,r,loc,y,0
NSLA,s,1
*get,ncount,node,,count

*DO,i,1,ncount,1
*GET,nmax,node,0,num,max
E,2,nmax
NSEL,u,node,,nmax
*ENDDO
CSYS,0

FINISH
/SOLU

ANTYPE,0 ! static analyse: on
NLGEOM,1 ! nonlinear geometry: on

DELTIM,delta_t,delta_t_min,delta_t_max ! steps of iteration
OUTRES,ALL,ALL ! write out all the solutions
AUTOTS,1 ! automatic increment regulation
NEQIT,200

! hinged support
NSEL,s,loc,x,width/2
NSEL,r,loc,y,-ymn
NSEL,r,loc,z,0
D,all,UX,0,,,,UY,UZ,ROTX,ROTY

CSYS,12
NSEL,s,loc,x,-width/2
NSEL,r,loc,y,-ymn
NSEL,r,loc,z,0
D,all,UX,0,,,,UY,UZ,ROTX,ROTY
CSYS,0

ASEL,s,loc,x,0
ESLA,s
SFE,all,,PRES,,1e3 ! pressure will be much larger
ALLSEL

SOLVE
FINISH
/POST1

set,last
! set,1,1
! set,next
PLESOL,S,EQV