Contact problem log file/macro

[ankushaggarwal2]

Thank you very much. As I told in my previous post, that when I try to run some contact problem on ANSYS 10.0, it just crashes without any warning or error messages (neither in log file nor in err file). I tried to run the same problem on other system with ANSYS 10.0 installed, but the problem is same there. Although it runs on ANSYS 9.

As I have not done any contact problem before, I doubt that I myself can be making some mistake. If you can provide me log file or macro of any simplest problem in ANSYS, it will be really helpful to check the problem.

Thank you very much.

 

[bridgehl]

Hi, I have the same problem many times. I think that Ansys is crashed and terminated by the OS. It is not something relating to non-converge solution. In this case, you even cannot restart your analysis. However, you can still check the result file to know what happened.

Because my problem takes a long time to finish, I utilized multiframe restart to reanalyze when Ansys is crashed.

Regards,

 

[ankushaggarwal2]

But is there any way to prevent this? In my case it crashes even for a simple tutorial problem. If you can send me some macro or log file of a very simple contact problem that runs on your ANSYS, I can check if I am doing something wrong or problem is elsewhere.

Thank you very much.

 

[bridgehl]

This analysis run successfully on my Ansys. Try it!




PNAME='MovingLoad' ! Problem file name

/FILNAME, PNAME, ON

/PREP7
ET, 1, SOLID45
MP, EX, 1, 2.857E10
MP, PRXY, 1, 0.3
MP, DENS, 1, 7850

MP, EX, 2, 2.857E10
MP, PRXY, 2, 0.3
MP, DENS, 2, 0

bb= 1
hh= 0.5
ll= 10


ESIZE, 0.5, 0,

ESEL, NONE
VSEL, NONE
NSEL, NONE
BLOCK, 0, ll, -hh, 0, -(bb/2), (bb/2),
TYPE, 1
MAT, 1
VMESH, ALL
CM, E_BEAM, ELEM
CM, N_BEAM, NODE
NSEL, R, LOC, Y, 0
CM, N_TARGET, NODE

ESIZE, 0.25, 0,

ESEL, NONE
VSEL, NONE
NSEL, NONE
BLOCK, 0, hh, 0, (hh/2), -(bb/2), (bb/2),
TYPE, 1
MAT, 2
VMESH, ALL
CM, E_TIRE, ELEM
CM, N_TIRE, NODE
NSEL, R, LOC, Y, 0
CM, N_CONTA, NODE


ET, 2, COMBIN40 ! Spring-mass-damper elements for wheels (standard gap)
KEYOPT, 2, 1, 1 ! Standard gap=0/ Lock on contact=1,
KEYOPT, 2, 3, 2 ! Element DOF X=1/ Y=2/ Z=3/...
KEYOPT, 2, 6, 2 ! Mass on node J

R, 2, 0, 0, 5000, 0, 0, 200000 ! K1, C, M, GAP, FSLIDE, K2

N, 10000, 0.25, 0.5, 0

TYPE, 2 ! Sping-mass-damper COMBIN40
REAL, 2
ESEL, NONE
E, NODE(0.25, 0.25, 0), 10000
CM, E_MASS, ELEM


NSEL, S, LOC, X, 0
NSEL, R, LOC, Y, -hh
CM, N_HINGED, NODE

NSEL, S, LOC, X, ll
NSEL, R, LOC, Y, -hh
CM, N_ROLLER, NODE


!==========================================================================================================
! CONTACT PAIRS MODELING
!==========================================================================================================

MAT, 1

ET, 2000, 170 ! Target
ET, 3000, 174 ! Contact surface-to-surface
!ET, 3000, 175 ! Contact node-to-surface
R, 3000, , , 1, 0.1, 0,
!RMORE, , , 1.0E20, 0.0, 1.0,
!RMORE, 0.0, 0, 1.0, , 1.0, 0.5
!RMORE, 0, 1.0, 1.0, 0.0, , 1.0
!RMORE, 10.0
KEYOPT, 3000, 1, 0
KEYOPT, 3000, 2, 0 ! Augmented Lagrange 0, Penalty Method 1
KEYOPT, 3000, 4, 0
KEYOPT, 3000, 5, 3 ! Close gap 1/ Reduces initial penetration 2/ Both 3
KEYOPT, 3000, 7, 2 ! Automatic bisection of increment 1, maintain reasonable 2
KEYOPT, 3000, 8, 0
KEYOPT, 3000, 9, 0 ! Include 0 / Exclude initial penetration 1
KEYOPT, 3000, 10, 2 ! Update contact stiffness at each iteration
KEYOPT, 3000, 11, 0 ! Beam/Shell thickness effect 1
KEYOPT, 3000, 12, 2 ! No separation

REAL, 3000
NSEL, S, , , N_TARGET
TYPE, 2000
ESLN, S, 0
ESURF

! Generate the contact surface
NSEL, S, , , N_CONTA
TYPE, 3000
ESLN, S, 0
ESURF

ALLSEL, ALL

/VIEW,1,1,1,1
/ANG,1
/REP,FAST

!==========================================================================================================
! SOLUTION
!==========================================================================================================

/SOL ! Analysis
/OUTPUT, PNAME, 'output', '',

VT= 15 !m/s

w1= (2.3239) ! Frequency of the first mode
w2= (3.0149) ! Frequency of the second mode
xi= 0.02 ! Constant damping ratio (2%)
adamp= (2*xi*w1*w2)/(w1+w2) ! External damping coefficient
bdamp= (2*xi)/(w1+w2) ! Internal damping coefficient
ALPHAD, adamp
BETAD, bdamp

D, N_HINGED, UX, 0, , , , UY, UZ
D, N_ROLLER, UY, 0, , , , UZ,
D, N_TIRE, UZ, 0
D, 10000, UZ, 0

TSTEP= 0.0015

ANTYPE, TRANS
NROPT, FULL
LUMPM, ON
NLGEOM, ON
LNSRCH, AUTO
SOLCONTROL, ON
AUTOTS, OFF

OUTRES, ALL, ALL


D, N_TIRE, UY, 0
D, N_TIRE, UX, 0
D, 10000, UX, 0
CMACEL, E_MASS, , 10, , ! Apply gravitational acceleration on mass dofs of vehicle only
TIMINT, OFF
KBC, 1 ! Stepped load
TIME, 0.001
NSUBST, 2
SOLVE


DDELE, N_TIRE, UY
*DIM, XDISP, TABLE, 2, 1, 1, TIME, , , 0
D, N_TIRE, UX, %XDISP%
D, 10000, UX, %XDISP%
XDISP(1, 0)= 0, (ll)/VT
XDISP(1, 1)= 0, (ll)


TIMINT, ON
KBC, 0 ! Ramped load
TIME, ((ll-0.5)/VT)
DELTIM, TSTEP
SOLVE

/OUTPUT, TERM
SAVE
FINISH