×
INTELLIGENT WORK FORUMS
FOR ENGINEERING PROFESSIONALS

Log In

Come Join Us!

Are you an
Engineering professional?
Join Eng-Tips Forums!
  • Talk With Other Members
  • Be Notified Of Responses
    To Your Posts
  • Keyword Search
  • One-Click Access To Your
    Favorite Forums
  • Automated Signatures
    On Your Posts
  • Best Of All, It's Free!
  • Students Click Here

*Eng-Tips's functionality depends on members receiving e-mail. By joining you are opting in to receive e-mail.

Posting Guidelines

Promoting, selling, recruiting, coursework and thesis posting is forbidden.

Students Click Here

Jobs

looking for a USA flag block or drawing

looking for a USA flag block or drawing

looking for a USA flag block or drawing

(OP)
looking for a USA flag block or drawing.
thanks.

RE: looking for a USA flag block or drawing

Try this



;;           ***** USA.LSP *****
;;
;;   Creates the United States of America banner.
;;   Use black screen background for best results.
;;
;;   W. Kilbourne, CompugraphX, Revised October 1, 2001
;;
(defun c:USA (/ CE BM OS OE SP HT XD XA EP YA D1 D2 D3 D4 RP RH XZ YZ
                P1 P2 P3 P4 P5 P6 P7 P8 P9 PX PY PZ S1 S2 S3 S4 S5 S6)
   (setq CE (getvar "CMDECHO") BM (getvar "BLIPMODE") OM (getvar "OSMODE"))
   (defun NE (NE) (setvar "CMDECHO" CE) (setvar "BLIPMODE" BM)
      (setvar "OSMODE" OM) (princ "Function cancelled ") (princ)
   )
   (setq OE *error* *error* NE)
   (setvar "CMDECHO" 0) (setvar "OSMODE" 0)
   (while (= SP nil)
      (setq SP (getpoint "\nPick lower left corner of flag: "))
   )
   (while (= HT nil)
      (setq HT (getcorner SP "\nPick upper right corner of flag <height>: "))
   )
   (if (>= (angle SP HT)(/ pi 2))
      (setq HT (polar SP (/ pi 4) (distance SP HT)))
   )
   (setq XD (distance SP HT)
         XA (angle SP HT)
         EP (polar SP (/ pi 2) (* XD (sin XA)))
         YA (angle SP EP)
         D1 (distance SP EP)
         D2 (/ D1 13)
         D3 (* D2 0.8)
         D4 (* D2 1.4)
         RP (polar SP 0.0 (* D1 1.5))
         RH (polar EP 0.0 (* D1 1.5))
         XZ (polar SP (* pi 1.25) D2)
         YZ (polar RH (* pi 0.25) D2)
         P1 (polar SP (/ pi 2) (* D2 6))
         P2 (polar P1 0.0 (* D2 8.5))
         P3 (polar EP 0.0 (* D2 8.5))
         P4 (polar SP YA D2)
         P5 (polar RP YA D2)
         P6 (polar P4 YA D2)
         P7 (polar P5 YA D2)
         P8 (polar RP YA (* D2 6))
         P9 (polar P2 YA D2)
         PX (polar P8 YA D2)
         PY (polar P9 YA D2)
         PZ (polar PX YA D2)
         S1 (polar P1 (* pi 0.25) D2)
         S2 (polar S1 (* pi 0.3) (* D3 0.172))
         S3 (polar S1 (* pi 0.7) (* D3 0.172))
         S4 (polar S1 YA (* D3 0.43952))
         S5 (polar S1 (* pi 0.25) D2)
         S6 (polar P3 (* pi 1.25) D4)
   )
   (command ".BLIPMODE" "OFF"
            ".FILL" "ON"
            ".ZOOM" "W" XZ YZ
            ".LAYER" "N" "BLUE" "C" "5" "BLUE" "S" "BLUE" ""
            ".SOLID" P1 P2 EP P3 ""
            ".LAYER" "N" "RED" "C" "1" "RED" "S" "RED" ""
            ".SOLID" SP P4 RP P5 ""
            ".ARRAY" "L" "" "R" "3" "1" (* D2 2)
            ".SOLID" P2 P9 P8 PX ""
            ".ARRAY" "L" "" "R" "4" "1" (* D2 2)
            ".LAYER" "N" "WHITE" "C" "7" "WHITE" "S" "WHITE" ""
            ".SOLID" P4 P6 P5 P7 ""
            ".ARRAY" "L" "" "R" "3" "1" (* D2 2)
            ".SOLID" P9 PY PX PZ ""
            ".ARRAY" "L" "" "R" "3" "1" (* D2 2)
            ".SOLID" S1 S2 S3 S4 ""
            ".ARRAY" "L" "" "P" S1 "5" "360" "Y"
            ".ARRAY" "W" P1 S5 "" "R" "5" "6" D4 D4
            ".COPY" "W" P1 S6 "" S1 S5
   )
   (setvar "CMDECHO" CE)
   (setvar "BLIPMODE" BM)
   (setvar "OSMODE" OM)
   (setq *error* OE OE nil)
   (princ)
)

Charles S. Parnell
Southern Store Fixtures

Red Flag This Post

Please let us know here why this post is inappropriate. Reasons such as off-topic, duplicates, flames, illegal, vulgar, or students posting their homework.

Red Flag Submitted

Thank you for helping keep Eng-Tips Forums free from inappropriate posts.
The Eng-Tips staff will check this out and take appropriate action.

Reply To This Thread

Posting in the Eng-Tips forums is a member-only feature.

Click Here to join Eng-Tips and talk with other members!


Resources