×
INTELLIGENT WORK FORUMS
FOR ENGINEERING PROFESSIONALS

Log In

Come Join Us!

Are you an
Engineering professional?
Join Eng-Tips Forums!
  • Talk With Other Members
  • Be Notified Of Responses
    To Your Posts
  • Keyword Search
  • One-Click Access To Your
    Favorite Forums
  • Automated Signatures
    On Your Posts
  • Best Of All, It's Free!
  • Students Click Here

*Eng-Tips's functionality depends on members receiving e-mail. By joining you are opting in to receive e-mail.

Posting Guidelines

Promoting, selling, recruiting, coursework and thesis posting is forbidden.

Students Click Here

Jobs

rotating a hollow cylinder

rotating a hollow cylinder

rotating a hollow cylinder

(OP)
Dear all,
i've built a hollow cylinder which is enclosed at the lower end, and meshed it with solid186.
The model is fully constrained (ux,uy,uz=0), and i'm trying to apply a rotation of 20 to 30 degrees at the enclosed end.
however, when i tried applying the rotation (just 1 degree), enclosed end exhibit out of plane movement(did not rotate as a whole)

below is a batch file of one of the method i used, can anyone take a look at it and give me some advice
Thanks

!!!!!!!!!!!!!
!DEFINE PARAMETERS FOR CYLINDER (MM)


THK=10                    !THICKNESS
EXTRAD=35                !EXTERNAL RADIUS
INTRAD=35-THK                !INTERNAL RADIUS
TOPZ=0                    !Z COORDINATES (CYLINDER WALL)
BOTZ=80
BASTHK=2                !Z COORDINATES (FROM BASAL)


/PREP7


ET,1,SOLID186                !ELEMENT & MATERIAL PROPERTIES        
    
MP,NUXY,1,0.499                !APPROXIMATELY INCOMPRESSIBLE
MP,EX,1,31E-3                !MODULUS 31KPA

NUMSTR,VOLU,100                !STARTING VOLUME NO.(SEPERATE ENTITY)

CYLIND,INTRAD,EXTRAD,0,80,,        !CREATE HOLLOW CYLINDER
CYLIND,EXTRAD,,(BOTZ-THK),BOTZ        !CREATE APICAL CAP


NUMSTR,VOLU,50                !STARTING VOLUME NO.(AFTER VOVLAP)
BOPT,NUMB,OFF                
VOVLAP,100,101
BOPT,NUMB,ON

WPROTA,,90,                !ROTATE WORKPLANE (THXY,THYZ,THZX)                
VSBW,ALL                !SPLIT VOLUME INTO 2 BY WORKPLANE
WPROTA,,,90
NUMSTR,VOLU,1                !STARTING VOLUME NO.(AFTER BOOLEAN)
VSBW,ALL


!!!!MAPPED MESHING!!!!

LSEL,S,,,1,16,1,,            !SELECT CIRCUMFERENTIAL LINES
LSEL,A,,,21,24                !CREATE 9 DIVISIONS ON SELECTED LINES    
LSEL,A,,,51,53,2            !36 DIVISIONS ON CIRCUMFERENCE
LSEL,A,,,42,48,6            !EACH ELEMENT SPANS 9 DEGREE
LESIZE,ALL,,,10,,            
LSEL,ALL                


LSEL,S,,,19,25,6            !WALL THICKNESS DEFINED BY 4 ELEMENTS
LSEL,A,,,27,28                !EACH ELEMENT WITH EQUAL THICKNESS
LSEL,A,,,54,63,3            !2.5MM EACH ACROSS WALL TRANSMURALLY
LSEL,A,,,20,26,6
LSEL,A,,,56,59,3
LESIZE,ALL,,,4,,
LSEL,ALL


LSEL,S,,,33,39,6            !SELECT VERTICAL LINES
LSEL,A,,,44,58,14            !CREATE 16 DIVISIONS EQUALLY
LSEL,A,,,34,40,6            !ACROSS HEIGHT OF HOLLOW CYLINDER
LSEL,A,,,52,55,3            !EACH ELEMENT IS 5MM IN THICKNESS
LESIZE,ALL,,,2,,
LSEL,ALL
LSEL,S,,,35,38
LSEL,A,,,61,62
LSEL,A,,,64,65
LESIZE,ALL,,,14,,
LSEL,ALL


MSHAPE,0                !HEXAHEDRA SHAPED ELEMENTS
MSHKEY,1                !MAPPED MESHING
VMESH,ALL                !MESH ALL VOLUMES


/SOLU

!!!!APPLY BOUNDARY CONDITIONS!!!!

ASEL,S,LOC,Z,0                !SELECT NODES ATTACHED TO
NSLA,R,1                !BASAL SURFACE
D,ALL,ALL                !FULLY CONSTRAINED AT BASAL TOP
ASEL,ALL
NSEL,ALL

!!!!APPLY APICAL ROTATION!!!!

CSYS,1                    !CYLINDRICAL COORDINATE SYSTEM
*AFUN,DEG                !DEGREES
DRT=5                    !DRT EQUALS 5 DEGREES

VSEL,S,,,7                !WALL AT 1ST QUADRANT
NSLV,R,1                !SELECT ATTACHED NODES
NSEL,R,LOC,Y,DRT,90
NSEL,R,LOC,X,35

D,ALL,UX,EXTRAD-EXTRAD*COS(DRT)
D,ALL,UY,-EXTRAD*SIN(DRT)
NSEL,ALL


VSEL,S,,,5                !WALL AT 2ND QUADRANT
NSLV,R,1                !SELECT ATTACHED NODES
NSEL,R,LOC,Y,90+DRT,180
NSEL,R,LOC,X,35

D,ALL,UX,EXTRAD-EXTRAD*COS(DRT)
D,ALL,UY,EXTRAD*SIN(DRT)
NSEL,ALL

VSEL,S,,,6                !WALL AT 3RD QUADRANT
NSLV,R,1                !SELECT ATTACHED NODES
NSEL,R,LOC,Y,180+DRT,270
NSEL,R,LOC,X,35

D,ALL,UX,EXTRAD*COS(DRT)-EXTRAD
D,ALL,UY,EXTRAD*SIN(DRT)
NSEL,ALL


VSEL,S,,,8                !WALL AT 4TH QUADRANT
NSLV,R,1                !SELECT ATTACHED NODES
NSEL,R,LOC,Y,270+DRT,360
NSEL,R,LOC,X,35

D,ALL,UX,EXTRAD*COS(DRT)-EXTRAD
D,ALL,UY,-EXTRAD*SIN(DRT)
NSEL,ALL
VSEL,ALL


SOLVE

RE: rotating a hollow cylinder

Hello, ywioywio!

I try to run your input and indeed I have the same problem that you reported.
So I took a look of the input and I've seen that the rotation is not correctly applied.
Please try this version that is similar with yours except my corrections.

Please note that the correct displacement conditions are:

alfa = the angle of the node where rotation is applied in
       cylindrical coordinate (degree)
ux = extrad*cos(alfa+drt)-extrad*cos(alfa)
uy = extrad*sin(alfa+drt)-extrad*sin(alfa)

for all quadrants and all nodes that rotation is applied.

I hope that will be helpful!

Best regards,

juzz  



!!!!!!!!!!!!!
!DEFINE PARAMETERS FOR CYLINDER (MM)


THK=10                    !THICKNESS
EXTRAD=35                !EXTERNAL RADIUS
INTRAD=35-THK                !INTERNAL RADIUS
TOPZ=0                    !Z COORDINATES (CYLINDER WALL)
BOTZ=80
BASTHK=2                !Z COORDINATES (FROM BASAL)


/PREP7


ET,1,SOLID186                !ELEMENT & MATERIAL PROPERTIES        
    
MP,NUXY,1,0.499                !APPROXIMATELY INCOMPRESSIBLE
MP,EX,1,31E-3                !MODULUS 31KPA

NUMSTR,VOLU,100                !STARTING VOLUME NO.(SEPERATE ENTITY)

CYLIND,INTRAD,EXTRAD,0,80,,        !CREATE HOLLOW CYLINDER
CYLIND,EXTRAD,,(BOTZ-THK),BOTZ        !CREATE APICAL CAP


NUMSTR,VOLU,50                !STARTING VOLUME NO.(AFTER VOVLAP)
BOPT,NUMB,OFF                
VOVLAP,100,101
BOPT,NUMB,ON

WPROTA,,90,                !ROTATE WORKPLANE (THXY,THYZ,THZX)                
VSBW,ALL                !SPLIT VOLUME INTO 2 BY WORKPLANE
WPROTA,,,90
NUMSTR,VOLU,1                !STARTING VOLUME NO.(AFTER BOOLEAN)
VSBW,ALL


!!!!MAPPED MESHING!!!!

LSEL,S,,,1,16,1,,            !SELECT CIRCUMFERENTIAL LINES
LSEL,A,,,21,24                !CREATE 9 DIVISIONS ON SELECTED LINES    
LSEL,A,,,51,53,2            !36 DIVISIONS ON CIRCUMFERENCE
LSEL,A,,,42,48,6            !EACH ELEMENT SPANS 9 DEGREE
LESIZE,ALL,,,10,,            
LSEL,ALL                


LSEL,S,,,19,25,6            !WALL THICKNESS DEFINED BY 4 ELEMENTS
LSEL,A,,,27,28                !EACH ELEMENT WITH EQUAL THICKNESS
LSEL,A,,,54,63,3            !2.5MM EACH ACROSS WALL TRANSMURALLY
LSEL,A,,,20,26,6
LSEL,A,,,56,59,3
LESIZE,ALL,,,4,,
LSEL,ALL


LSEL,S,,,33,39,6            !SELECT VERTICAL LINES
LSEL,A,,,44,58,14            !CREATE 16 DIVISIONS EQUALLY
LSEL,A,,,34,40,6            !ACROSS HEIGHT OF HOLLOW CYLINDER
LSEL,A,,,52,55,3            !EACH ELEMENT IS 5MM IN THICKNESS
LESIZE,ALL,,,2,,
LSEL,ALL
LSEL,S,,,35,38
LSEL,A,,,61,62
LSEL,A,,,64,65
LESIZE,ALL,,,14,,
LSEL,ALL


MSHAPE,0                !HEXAHEDRA SHAPED ELEMENTS
MSHKEY,1                !MAPPED MESHING
VMESH,ALL                !MESH ALL VOLUMES


/SOLU

!!!!APPLY BOUNDARY CONDITIONS!!!!

ASEL,S,LOC,Z,0                !SELECT NODES ATTACHED TO
NSLA,R,1                !BASAL SURFACE
D,ALL,ALL                !FULLY CONSTRAINED AT BASAL TOP
ASEL,ALL
NSEL,ALL

!!!!APPLY APICAL ROTATION!!!!

CSYS,1                    !CYLINDRICAL COORDINATE SYSTEM
*AFUN,DEG                !DEGREES
DRT=5                    !DRT EQUALS 5 DEGREES

NSEL,S,LOC,Z,BOTZ-THK,BOTZ    ! sELECT NODES AT BOTTOM
NSEL,R,LOC,X,EXTRAD        ! sELECT NODES AT EXTERNAL DIAMETER
*GET,FN,NODE,0,NUM,MIN        ! THE LOWER NUMBERED NODE IN SELECTION
*GET,TN,NODE,0,COUNT        ! THE NUMBER OF NODES IN SELECTION
*DO,I,1,TN,1
    D,FN,UX,EXTRAD*COS(NY(FN)+DRT)-EXTRAD*COS(NY(FN))
    D,FN,UY,EXTRAD*SIN(NY(FN)+DRT)-EXTRAD*SIN(NY(FN))
    FN=NDNEXT(FN)
*ENDDO

SOLVE

!    FN IS CURRENT NODE THAT IS CYCLED FOR APPLYING
!       ROTATION
!    TN IS THE TOTAL NUMBER OF NODES THAT ROTATION IS
!       APPLIED

RE: rotating a hollow cylinder

(OP)
thanks for your help
i'll try this model

Red Flag This Post

Please let us know here why this post is inappropriate. Reasons such as off-topic, duplicates, flames, illegal, vulgar, or students posting their homework.

Red Flag Submitted

Thank you for helping keep Eng-Tips Forums free from inappropriate posts.
The Eng-Tips staff will check this out and take appropriate action.

Reply To This Thread

Posting in the Eng-Tips forums is a member-only feature.

Click Here to join Eng-Tips and talk with other members!


Resources