×
INTELLIGENT WORK FORUMS
FOR ENGINEERING PROFESSIONALS

Log In

Come Join Us!

Are you an
Engineering professional?
Join Eng-Tips Forums!
  • Talk With Other Members
  • Be Notified Of Responses
    To Your Posts
  • Keyword Search
  • One-Click Access To Your
    Favorite Forums
  • Automated Signatures
    On Your Posts
  • Best Of All, It's Free!
  • Students Click Here

*Eng-Tips's functionality depends on members receiving e-mail. By joining you are opting in to receive e-mail.

Posting Guidelines

Promoting, selling, recruiting, coursework and thesis posting is forbidden.

Students Click Here

Jobs

PSPICE MOSFETS vs. Berekely SPICE3F5 MOSFETS

PSPICE MOSFETS vs. Berekely SPICE3F5 MOSFETS

PSPICE MOSFETS vs. Berekely SPICE3F5 MOSFETS

(OP)
Hello,

I have a model for a Motorola MOSFET - mtp6n60/mc. I get an error about several mosfet parameters (LAMBDA one of them) when trying to simulate it in Multisim- an XPICE/SPICE3F5 based simulator. The model is specified as a "Level 3" mosfet and according to SPICE3F5 specs, the error inducing parameters are not supported in level 3, so the error makes sense. In fact, no SPICE model level supports the set of parameters in my model. My guess is that this model is created specificaly for PSPICE or HSPICE who deviate from SPICE3F5 slightly.

Does anyone have a suggestion on how to simulate this model in basic Berkely SPICE3F5?

Here's the model:

.subckt mtp6n60/mc 10 20 30


* 10 = Drain 20 = Gate 30 = Source
*
******************************************************************************
*
*------------------------ EXTERNAL PARASITICS --------------------------------
* PACKAGE INDUCTANCE
*
LDRAIN  10  11  4.5e-09
LGATE   20  21  7.5e-09
LSOURCE 30  31  7.5e-09
*
* RESISTANCES
*
RDRAIN1    4  11 RDRAIN 0.8036
RDRAIN2    4   5 RDRAIN 0.0084
RSOURCE   31   6 RSOURCE 0.02018  
RDBODY     8  30 RDBODY  0.0135
*
RGATE      21   2 5
*
*--------------------------------------------------------------------------
*
*--------------- CAPACITANCES AND BODY DIODE ------------------------------
*
DBODY       8  11 DBODY
DGD         3  11 DGD
CGDMAX      2   3 2.7e-09
RGDMAX      2   3 1e+08
CGS         2   6 1.31e-09
*
*--------------------------------------------------------------------------
*
*----------------------- CORE MOSFET --------------------------------------
*
M1       5  2  6  6  MAIN
*
*--------------------------------------------------------------------------
*
.MODEL RDRAIN RES  (
+TC1    = 0.008891
+TC2    = 3.056e-05)
*
.MODEL RSOURCE RES  (
+TC1    = -0.003198
+TC2    = 2.60004e-05)
*
.MODEL RDBODY RES  (
+TC1    = 0.003945
+TC2    = 9.54752e-06)
*
*
.MODEL MAIN NMOS  (
+LEVEL   = 3
+VTO     = 3.8
+KP      = 13
+GAMMA   = 2.6
+PHI     = 0.6
+LAMBDA  = 0.0019
+RD      = 0
+RS      = 0
+CBD     = 0
+CBS     = 0
+IS      = 1e-14
+PB      = 0.8
+CGSO    = 0
+CGDO    = 0
+CGBO    = 0
+RSH     = 0
+CJ      = 0
+MJ      = 0.5
+CJSW    = 0
+MJSW    = 0.33
+JS      = 1e-14
+TOX     = 1e-07
+NSUB    = 1e+15
+NSS     = 0
+NFS     = 6.59e+11
+TPG     = 1
+XJ      = 0
+LD      = 0
+UO      = 600
+UCRIT   = 1000
+UEXP    = 0
+UTRA    = 0
+VMAX    = 0
+NEFF    = 1
+KF      = 0
+AF      = 1
+FC      = 0.5
+DELTA   = 0
+THETA   = 0
+ETA     = 0
+KAPPA   = 0.2)
*
*--------------------------------------------------------------------------
*
.MODEL DGD D  (
+IS      = 1e-15
+RS      = 0
+N       = 1000
+TT      = 0
+CJO     = 1.129e-09
+VJ      = 1.943
+M       = 1.476
+EG      = 1.11
+XTI     = 3
+KF      = 0
+AF      = 1
+FC      = 0.5
+BV      = 10000
+IBV     = 0.001)
*
*--------------------------------------------------------------------------
*
.MODEL DBODY D  (
+IS      = 1.532e-11
+RS      = 0
+N       = 1.062
+TT      = 2.5e-07
+CJO     = 9.725e-10
+VJ      = 1.127
+M       = 0.6627
+EG      = 1.11
+XTI     = 5
+KF      = 0
+AF      = 1
+FC      = 0.5
+BV      = 671
+IBV     = 0.00025)
.ENDS



RE: PSPICE MOSFETS vs. Berekely SPICE3F5 MOSFETS

But what's not supported?  Can you move those parameters and related parasitics to be an external component?

TTFN



RE: PSPICE MOSFETS vs. Berekely SPICE3F5 MOSFETS

(OP)
I should've been slightly more clear. My simulator complains about the actual NMOS SPICE element in the subcircuit.  This guy:

.MODEL MAIN NMOS  (
+LEVEL   = 3
+VTO     = 3.8
+KP      = 13
+GAMMA   = 2.6
+PHI     = 0.6
+LAMBDA  = 0.0019
+RD      = 0
.
.)

It doesn't like lambda amongst a few others at LEVEL 3. Lamda for instance is only supported for LEVEL 1 and 2 as per SPICE manuals.




RE: PSPICE MOSFETS vs. Berekely SPICE3F5 MOSFETS

Max
all those parameters in your nmos model except LAMBDA are
supported in Level 1,2.

Lambda is the channel length modulation parameter.
It will affect the drain to source current with fixed
gate voltage in the saturation region. More lambda makes
a steeper increase in current as Vds increases.

I would enter the formula but there are two many unsupported symbol types.

You can do two things.
change Level back to 1  or remove the lambda value.

In either case build a test circuit in spice after you
change the model and compare the response to data sheet
values. Try to enter a circuit just like the data sheet
and check curves.

RE: PSPICE MOSFETS vs. Berekely SPICE3F5 MOSFETS

Max
Correction
I meant to say all the parameters are supported in level 3
except LAMBDA.

All the parameters listed are included in level 1.
So this really is a level 1 model.
My recommendation is to change level to 1.

Many of the parameters in the higher levels are designed to
account for the tiny geometries in very small mosfets found
on chips. They are not needed for power devices.

RE: PSPICE MOSFETS vs. Berekely SPICE3F5 MOSFETS

(OP)
no, many are not supported in level 1. The entire set of parameters as they are, cannot be supported by any unmodified SPICE simulator, at any MOSFET level.

Here's a table of which many copies I have seen:

http://www.seas.upenn.edu/~jan/spice/spice.MOSparamlist.html

RE: PSPICE MOSFETS vs. Berekely SPICE3F5 MOSFETS

Sorry
I didn't realize your 17:45 post was an abbreviated
version of your model.

Some of the parameters are Level 2 only.
UCRIT - UEXP - UTRA - NEFF

If you remove CBD and CBS the rest fit into level 2.

Thats about the best I can do.

Good luck

Red Flag This Post

Please let us know here why this post is inappropriate. Reasons such as off-topic, duplicates, flames, illegal, vulgar, or students posting their homework.

Red Flag Submitted

Thank you for helping keep Eng-Tips Forums free from inappropriate posts.
The Eng-Tips staff will check this out and take appropriate action.

Reply To This Thread

Posting in the Eng-Tips forums is a member-only feature.

Click Here to join Eng-Tips and talk with other members!


Resources